IOController_i.idl

См. документацию.

/* This file is part of the UniSet project
 * Copyright (c) 2002 Free Software Foundation, Inc.
 * Copyright (c) 2002 Pavel Vainerman
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; either version 2 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
 */
// --------------------------------------------------------------------------
// --------------------------------------------------------------------------
#ifndef BaseIOController_i_IDL_
#define BaseIOController_i_IDL_
// --------------------------------------------------------------------------
#include "../UniSetTypes/UniSetTypes_i.idl"
#include "../UniSetTypes/UniSetManager_i.idl"
// --------------------------------------------------------------------------------------------------------------

interface IOController_i : UniSetManager_i
{
    // исключения

    exception NameNotFound
    {
        string err;
    };

    exception IOBadParam
    {
        string err;
    };

    exception Undefined
    {
    };

    struct SensorInfo
    {
        UniSetTypes::ObjectId id;    
        UniSetTypes::ObjectId node;  
    };

    long getValue(in UniSetTypes::ObjectId sid) raises(NameNotFound,Undefined);
    void setValue(in UniSetTypes::ObjectId sid, in long value,
                    in UniSetTypes::ObjectId sup_id) raises(NameNotFound,Undefined);

    // установка неопределённого состояния
    // (пока работает только для аналоговых датчиков)
    void setUndefinedState(in UniSetTypes::ObjectId sid, in boolean undefined, in UniSetTypes::ObjectId sup_id )
                            raises(NameNotFound);

    // fast version (не вырабатывает исключения)
    oneway void fastSetValue(in UniSetTypes::ObjectId sid, in long value, in UniSetTypes::ObjectId sup_id);

    UniversalIO::IOType getIOType(in UniSetTypes::ObjectId sid) raises(NameNotFound);

    // --- Интерфейс для конфигурирования ---

    long getRawValue( in UniSetTypes::ObjectId sid ) raises(NameNotFound);

    struct CalibrateInfo
    {
        long minRaw;      
        long maxRaw;      
        long minCal;      
        long maxCal;      
        short precision;  
    };

    void calibrate( in UniSetTypes::ObjectId sid, in CalibrateInfo ci, in UniSetTypes::ObjectId adminId ) raises(NameNotFound);
    CalibrateInfo getCalibrateInfo( in UniSetTypes::ObjectId sid ) raises(NameNotFound);

    // --- Интерфес получения информации о всех датчиках ---
    struct SensorIOInfo
    {
        long value;                   
        boolean undefined;            
        boolean blocked;              
        long real_value;              
        UniversalIO::IOType type;     
        long priority;                
        IOController_i::SensorInfo si;
        long default_val;             
        CalibrateInfo ci;             
        long tv_sec;                  
        long tv_usec;                 
        boolean dbignore;             
    };

    typedef sequence<SensorIOInfo> SensorInfoSeq;

    SensorInfoSeq getSensorsMap();
    SensorIOInfo getSensorIOInfo( in UniSetTypes::ObjectId sid ) raises(NameNotFound);

    // -- Функции работы со списком датчиков --

    SensorInfoSeq getSensorSeq( in UniSetTypes::IDSeq lst );

    struct OutInfo
    {
        SensorInfo si;    
        long value;       
    };

    typedef sequence<OutInfo> OutSeq;

    UniSetTypes::IDSeq setOutputSeq( in OutSeq lst, in UniSetTypes::ObjectId sup_id );


    struct ShortIOInfo
    {
        long value;
        long tv_sec;    
        long tv_usec;   
    };

    ShortIOInfo getChangedTime( in UniSetTypes::ObjectId sid ) raises(NameNotFound);


    struct ShortMap
    {
        UniversalIO::IOType type;
        long value;
        long id;
    };

    typedef sequence<ShortMap> ShortMapSeq;

    ShortMapSeq getSensors();
};

// --------------------------------------------------------------------------------------------------------------
interface IONotifyController_i : IOController_i
{
    exception BadRange
    {
    };

    void askSensor(in UniSetTypes::ObjectId sid, in UniSetTypes::ConsumerInfo ci, in UniversalIO::UIOCommand cmd ) raises(NameNotFound,IOBadParam);

    UniSetTypes::IDSeq askSensorsSeq( in UniSetTypes::IDSeq lst,
                                        in UniSetTypes::ConsumerInfo ci,
                                        in UniversalIO::UIOCommand cmd );


    enum ThresholdState
    {
        LowThreshold,       
        NormalThreshold,    
        HiThreshold         
    };

    struct ThresholdInfo
    {
        UniSetTypes::ThresholdId id;
        long hilimit;         
        long lowlimit;        
        ThresholdState state;
        long tv_sec;          
        long tv_usec;         
        boolean invert;       
    };

    typedef sequence<ThresholdInfo> ThresholdInfoSeq;

    void askThreshold(in UniSetTypes::ObjectId sid, in UniSetTypes::ConsumerInfo ci, in UniSetTypes::ThresholdId tid,
                        in long lowLimit, in long hiLimit, in boolean invert,
                        in UniversalIO::UIOCommand cmd ) raises(NameNotFound, IOBadParam, BadRange);


    ThresholdInfo getThresholdInfo( in UniSetTypes::ObjectId sid, in UniSetTypes::ThresholdId tid ) raises(NameNotFound);

    struct ThresholdList
    {
        IOController_i::SensorInfo si;
        UniversalIO::IOType type;
        long value;
        ThresholdInfoSeq tlist;
    };

    typedef sequence<ThresholdList> ThresholdsListSeq;

    ThresholdList getThresholds( in UniSetTypes::ObjectId sid ) raises(NameNotFound);

    ThresholdsListSeq getThresholdsList();
};
// --------------------------------------------------------------------------
#endif